Эта статья расскажет вам, как создать такой популярный в современных
программах эффект, как "прилипание" окна к краю экрана, когда до него остается
небольшое расстояние. Реализуется это, как вы, наверное, догадываетесь, с
помощью Win API. Конечно, Win API не содержит функций, которые помогут окну
прилапать к краю экрана - нам придется немного разобраться с сообщениями
Windows. Обработка сообщений в Delphi реализована посредством событий; событие
обычно генерируется в ответ на сообщение Windows, посланное приложению.
Несмотря на то, что Delphi обрабатывает огромное количество сообщений,
некоторые из них все же "остаются без внимания". Например, мы знаем, что если
нашей программе нужно обработать изменение размера формы, то мы пишем обработчик
события OnResize - таким образом Delphi обрабатывает сообщение WM_SIZE, но вот
как определить, что форма передвигается по экрану? Форма Delphi получает
соответствующее сообщение, но не обрабатывает его.
Сообщение WM_MOVING посылается окну, которое передвигается пользователем.
Обработав это сообщение, приложение может получить информацию о размере и
позиции передвигаемого прямоугольника и, если нужно, изменить их.
Сообщение WM_WINDOWPOSCHANGING посылается окну, чьи размеры, позиция или
видимость должны измениться в результате вызова функции SetWindowPos или другой
функции управления окном.
Иногда простого факта, что событие произошло, недостаточно и нам необходима
дополнительная информация о нем. Например, приняв сообщение WM_MOVE мы узнаем
не только то, что положение формы изменилось, но и новые координаты X и Y нашего
окна.
Сообщение WM_WINDOWPOSCHANGING позволяет получить немного больше данных - мы
получаем указатель на структуру WindowPos, которая содержит информацию о новых
координатах и размере окна. Вот как эта структура описана:
TWindowPos = packed record
hwnd: HWND; {хэндл окна}
hwndInsertAfter: HWND; {Окно, находящееся над нашим}
x: Integer; {Координата Х левого края окна}
y: Integer; {Координата Y верхнего края окна}
cx: Integer; {Ширина окна}
cy: Integer; {Высота окна}
flags: UINT; {Различные характеристики окна}
end;
Наша задача проста: мы хотим, чтобы форма прилипала к краю экрана, если край
формы при перемещении оказывается на определенном расстояниии от края экрана
(скажем, 20 пикселей).
Теперь приступим к написанию собственно кода приложения. Создайте новую форму
и поместите на нее следующие компоненты: TLabel, поле ввода (TEdit) и четыре
чекбокса (TCheckBox). Задайте новое имя полю ввода - пусть это будет edStickAt.
Чекбоксы переименуйте в chkLeft, chkTop и т.д... Как вы, наверное, догадались, в
edStickAt содержится число пикселей, на которое нужно приблизить край формы к
краю экрана, чтобы форма "прилипла" к нему, а чекбоксы определяют поведение окна
вблизи соответствующих краев экрана. Форма будет выглядеть примерно так::
Единственное сообщение, которое нас интересует сейчас - WM_WINDOWPOSCHANGING.
Объявление обработчика этого сообщения находится в секции private объявления
формы. Далее приводится полный код процедуры "прилипания". Учтите, что вы можете
изменять поведение формы чекбоксами - при установленной галочке форма прилипает
к соответствующему краю экрана.
Для определения текущего размера рабочего стола Windows используется функция
SystemParametersInfo, в которую первым параметром передается константа
SPI_GETWORKAREA. Таким образом учитывается только свободное пространство
рабочего стола - не принимаются во внимание панель управления, панели Internet
Explorer'а и т.д.
...
private
procedure WMWINDOWPOSCHANGING
(Var Msg: TWMWINDOWPOSCHANGING);
message WM_WINDOWPOSCHANGING;
...
procedure TfrMain.WMWINDOWPOSCHANGING
(var Msg: TWMWINDOWPOSCHANGING);
const
Docked: Boolean = FALSE;
var
rWorkArea: TRect;
StickAt : Word;
begin
StickAt := StrToInt(edStickAt.Text);
SystemParametersInfo
(SPI_GETWORKAREA, 0, @rWorkArea, 0);
with Msg.WindowPos^ do begin
if chkLeft.Checked then
if x <= rWorkArea.Left + StickAt then begin
x := rWorkArea.Left;
Docked := TRUE;
end;
if chkRight.Checked then
if x + cx >= rWorkArea.Right - StickAt then begin
x := rWorkArea.Right - cx;
Docked := TRUE;
end;
if chkTop.Checked then
if y <= rWorkArea.Top + StickAt then begin
y := rWorkArea.Top;
Docked := TRUE;
end;
if chkBottom.Checked then
if y + cy >= rWorkArea.Bottom - StickAt then begin
y := rWorkArea.Bottom - cy;
Docked := TRUE;
end;
if Docked then begin
with rWorkArea do begin
// запрещаем перемещение за пределы экрана
if x < Left then x := Left;
if x + cx > Right then x := Right - cx;
if y < Top then y := Top;
if y + cy > Bottom then y := Bottom - cy;
end; {with rWorkArea}
end; {if Docked}
end; {with Msg.WindowPos^}
inherited;
end;
end.
Теперь просто запустите приложение и попробуйте придвинуть форму к краю
экрана.
Удачного программирования!
|